vb窗口最大化問題的解決方法

VB實現控件與窗體不能同步縮放呢？

為什么會出現這種情況呢？原因很簡單：當窗體的尺寸縮放(如最大化)時，窗體內的控件的尺寸以及在窗體內的相對位置沒有得到相應的調整。事實上，窗體和控件的大小分別是由窗體和控件的Width屬性和Height屬性確定的。所以，當程序界面設計完成之后，窗體及其內部各控件的Width、Height屬性便隨之確定下來；從而窗體相對于每一個控件，它們的寬度之比、高度之比也被確定下來。
例如：如果窗體Form1內的一個文本框控件Text1的寬度(Width)為3600，高度(Height)為1900，；而窗體Form1的這兩個值分別為4900和3700，則它們的寬度之比和高度之比分別為：3600／4900、1900／3700。而當用戶在程序啟動后調整了窗體的尺寸，則窗體的寬度和高度分別為Form1.ScaleWidth和Form1.ScaleHeight。由此可以看出，要保證控件與窗體之間的原有比例，只要按比例來調整文本框控件Text1的高度和寬度值即可。即：

　　調整后的Text1的Width值Κ(3600／4900)×Form1.ScaleWidth

　　調整后的Text1的Height值Κ(1900／3700)×Form1.ScaleHeight

　　將上面的例子中得出的結論推而廣之：一般而言，當窗體尺寸調整后，窗體內控件的尺寸應按以下公式同步進行調整：調整后的控件的Width值Κ(控件原Width值／窗體原Width值)×窗體.ScaleWidth；調整后的控件的Height屬性值Κ(控件原Height值／窗體原Height值)×窗體.ScaleHeight。

　　窗體尺寸縮放的同時，窗體內的控件在窗體中的相對位置應如何同步調整呢？控件在窗體中的位置由該控件的Left和Top屬性確定。程序啟動后如果窗體被縮放，只要按照縮放的比例來重新調整窗體內各控件的Left和Top屬性值即可。因此，根據上面介紹的同步調整控件尺寸的原理，在窗體被縮放的同時，只要按照下面的關系來設置控件的Left和Top值即可；調整后控件的Left值Κ(控件原Left值／窗體原Left值)×窗體.ScaleWidth；調整后控件的Top值Κ(控件原Top值／窗體原Top值)×窗體.ScaleHeight。

　　上面談了控件與窗體同步縮放及保持相對位置的原理，下面看看在VB程序中實現的具體方法。我們知道，Resize事件是窗體響應的一個事件；當窗體第一次顯示或當窗體的狀態被改變時(如窗體被最大化、最小化或被還原時)該事件發生。所以，只要將對控件大小和位置的調整代碼寫入窗體的Resize事件中便可達到目的。具體可在窗體的Re size事件過程中使用對象的Move方法：

　　PrivateSubForm-Resize()

　　Object.moveNewleft，Newtop，NewWidth，NewHeight

　　EndSub

　　其中：Object是需要調整大小和位置的任意一個控件的名稱；NewLeft、NewTop、NewWidth與NewHeight分別是窗體縮放后控件應有的新的Left、Top、Width與Height的屬性值，它們確定了當窗體被縮放后控件的大小和位置。NewWidth、NewHeight、NewLeft和NewTop可直接使用文中給出的相應公式的表達式。

　　最后要注意的是，不要對窗體內的不可見控件(如果有的話)進行類似的處理，否則會出錯。

下面的代碼可以實現，vb窗口最大化的時候，里面的控件一起變化

Option Explicit
Private InitWidth As Long ' Form 的原始大小
Private InitHeight As Long

Private Sub Form_Load()
InitWidth = ScaleWidth
InitHeight = ScaleHeight
Dim Ctl As Control
' 記錄每個 Control 的原始位置、大小、字型大小, 放在 Tag 屬性中
On Error Resume Next '確保left, top, width, height, Tag屬性沒有全有的Control
For Each Ctl In Me   '也能正常執行
    Ctl.Tag = Ctl.Left & " " & Ctl.Top & " " & Ctl.Width & " " & Ctl.Height & " "
    Ctl.Tag = Ctl.Tag & Ctl.FontSize & " "
Next Ctl
On Error GoTo 0
End Sub

Private Sub Form_Resize()
Dim D(4) As Double
Dim I As Long
Dim TempPos As Long
Dim StartPos As Long
Dim Ctl As Control
Dim TempVisible As Boolean
Dim ScaleX As Double
Dim ScaleY As Double

ScaleX = ScaleWidth / InitWidth
ScaleY = ScaleHeight / InitHeight
On Error Resume Next
For Each Ctl In Me
    TempVisible = Ctl.Visible
    Ctl.Visible = False
    StartPos = 1
    ' 讀取 Control 的原始位置、大小、字型大小
    For I = 0 To 4
        TempPos = InStr(StartPos, Ctl.Tag, " ", vbTextCompare)
        If TempPos > 0 Then
            D(I) = Mid(Ctl.Tag, StartPos, TempPos - StartPos)
            StartPos = TempPos + 1
        Else
            D(I) = 0
        End If
        ' 根據比例設定 Control 的位置、大小、字型大小
        Ctl.Move D(0) * ScaleX, D(1) * ScaleY, D(2) * ScaleX, D(3) * ScaleY
        'Ctl.Width = D(2) * ScaleX
        'Ctl.Height = D(3) * ScaleY
        If ScaleX < ScaleY Then
            Ctl.FontSize = D(4) * ScaleX
        Else
            Ctl.FontSize = D(4) * ScaleY
        End If
    Next I
    Ctl.Visible = TempVisible
Next Ctl
On Error GoTo 0
End Sub