vb窗口最大化問題的解決方法

VB實(shí)現(xiàn)控件與窗體不能同步縮放呢？

為什么會(huì)出現(xiàn)這種情況呢？原因很簡(jiǎn)單：當(dāng)窗體的尺寸縮放(如最大化)時(shí)，窗體內(nèi)的控件的尺寸以及在窗體內(nèi)的相對(duì)位置沒有得到相應(yīng)的調(diào)整。事實(shí)上，窗體和控件的大小分別是由窗體和控件的Width屬性和Height屬性確定的。所以，當(dāng)程序界面設(shè)計(jì)完成之后，窗體及其內(nèi)部各控件的Width、Height屬性便隨之確定下來；從而窗體相對(duì)于每一個(gè)控件，它們的寬度之比、高度之比也被確定下來。
例如：如果窗體Form1內(nèi)的一個(gè)文本框控件Text1的寬度(Width)為3600，高度(Height)為1900，；而窗體Form1的這兩個(gè)值分別為4900和3700，則它們的寬度之比和高度之比分別為：3600／4900、1900／3700。而當(dāng)用戶在程序啟動(dòng)后調(diào)整了窗體的尺寸，則窗體的寬度和高度分別為Form1.ScaleWidth和Form1.ScaleHeight。由此可以看出，要保證控件與窗體之間的原有比例，只要按比例來調(diào)整文本框控件Text1的高度和寬度值即可。即：

　　調(diào)整后的Text1的Width值Κ(3600／4900)×Form1.ScaleWidth

　　調(diào)整后的Text1的Height值Κ(1900／3700)×Form1.ScaleHeight

　　將上面的例子中得出的結(jié)論推而廣之：一般而言，當(dāng)窗體尺寸調(diào)整后，窗體內(nèi)控件的尺寸應(yīng)按以下公式同步進(jìn)行調(diào)整：調(diào)整后的控件的Width值Κ(控件原Width值／窗體原Width值)×窗體.ScaleWidth；調(diào)整后的控件的Height屬性值Κ(控件原Height值／窗體原Height值)×窗體.ScaleHeight。

　　窗體尺寸縮放的同時(shí)，窗體內(nèi)的控件在窗體中的相對(duì)位置應(yīng)如何同步調(diào)整呢？控件在窗體中的位置由該控件的Left和Top屬性確定。程序啟動(dòng)后如果窗體被縮放，只要按照縮放的比例來重新調(diào)整窗體內(nèi)各控件的Left和Top屬性值即可。因此，根據(jù)上面介紹的同步調(diào)整控件尺寸的原理，在窗體被縮放的同時(shí)，只要按照下面的關(guān)系來設(shè)置控件的Left和Top值即可；調(diào)整后控件的Left值Κ(控件原Left值／窗體原Left值)×窗體.ScaleWidth；調(diào)整后控件的Top值Κ(控件原Top值／窗體原Top值)×窗體.ScaleHeight。

　　上面談了控件與窗體同步縮放及保持相對(duì)位置的原理，下面看看在VB程序中實(shí)現(xiàn)的具體方法。我們知道，Resize事件是窗體響應(yīng)的一個(gè)事件；當(dāng)窗體第一次顯示或當(dāng)窗體的狀態(tài)被改變時(shí)(如窗體被最大化、最小化或被還原時(shí))該事件發(fā)生。所以，只要將對(duì)控件大小和位置的調(diào)整代碼寫入窗體的Resize事件中便可達(dá)到目的。具體可在窗體的Re size事件過程中使用對(duì)象的Move方法：

　　PrivateSubForm-Resize()

　　Object.moveNewleft，Newtop，NewWidth，NewHeight

　　EndSub

　　其中：Object是需要調(diào)整大小和位置的任意一個(gè)控件的名稱；NewLeft、NewTop、NewWidth與NewHeight分別是窗體縮放后控件應(yīng)有的新的Left、Top、Width與Height的屬性值，它們確定了當(dāng)窗體被縮放后控件的大小和位置。NewWidth、NewHeight、NewLeft和NewTop可直接使用文中給出的相應(yīng)公式的表達(dá)式。

　　最后要注意的是，不要對(duì)窗體內(nèi)的不可見控件(如果有的話)進(jìn)行類似的處理，否則會(huì)出錯(cuò)。

下面的代碼可以實(shí)現(xiàn)，vb窗口最大化的時(shí)候，里面的控件一起變化

Option Explicit
Private InitWidth As Long ' Form 的原始大小
Private InitHeight As Long

Private Sub Form_Load()
InitWidth = ScaleWidth
InitHeight = ScaleHeight
Dim Ctl As Control
' 記錄每個(gè) Control 的原始位置、大小、字型大小, 放在 Tag 屬性中
On Error Resume Next '確保left, top, width, height, Tag屬性沒有全有的Control
For Each Ctl In Me   '也能正常執(zhí)行
    Ctl.Tag = Ctl.Left & " " & Ctl.Top & " " & Ctl.Width & " " & Ctl.Height & " "
    Ctl.Tag = Ctl.Tag & Ctl.FontSize & " "
Next Ctl
On Error GoTo 0
End Sub

Private Sub Form_Resize()
Dim D(4) As Double
Dim I As Long
Dim TempPos As Long
Dim StartPos As Long
Dim Ctl As Control
Dim TempVisible As Boolean
Dim ScaleX As Double
Dim ScaleY As Double

ScaleX = ScaleWidth / InitWidth
ScaleY = ScaleHeight / InitHeight
On Error Resume Next
For Each Ctl In Me
    TempVisible = Ctl.Visible
    Ctl.Visible = False
    StartPos = 1
    ' 讀取 Control 的原始位置、大小、字型大小
    For I = 0 To 4
        TempPos = InStr(StartPos, Ctl.Tag, " ", vbTextCompare)
        If TempPos > 0 Then
            D(I) = Mid(Ctl.Tag, StartPos, TempPos - StartPos)
            StartPos = TempPos + 1
        Else
            D(I) = 0
        End If
        ' 根據(jù)比例設(shè)定 Control 的位置、大小、字型大小
        Ctl.Move D(0) * ScaleX, D(1) * ScaleY, D(2) * ScaleX, D(3) * ScaleY
        'Ctl.Width = D(2) * ScaleX
        'Ctl.Height = D(3) * ScaleY
        If ScaleX < ScaleY Then
            Ctl.FontSize = D(4) * ScaleX
        Else
            Ctl.FontSize = D(4) * ScaleY
        End If
    Next I
    Ctl.Visible = TempVisible
Next Ctl
On Error GoTo 0
End Sub